QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += QT_NO_VERSION_TAGGING

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

include($$PWD/../HGOEM.pri)

if (contains(DEFINES, OEM_HANWANG)) {
    TARGET = HanvonScan2
} else {
    if (contains(DEFINES, OEM_LISICHENG)) {
        TARGET = LanxumScan2
    } else {
        if (contains(DEFINES, OEM_CANGTIAN)) {
            TARGET = CumtennScan2
        } else {
            if (contains(DEFINES, OEM_ZHONGJING)) {
                TARGET = MicrotekScan2
            } else {
                if (contains(DEFINES, OEM_ZIGUANG)) {
                    TARGET = UniScan2
                } else {
                    if (contains(DEFINES, OEM_NEUTRAL)) {
                        TARGET = NeuScan2
                    } else {
                        if (contains(DEFINES, OEM_DELI)) {
                            TARGET = "DELI SCAN2"
                        } else {
                            TARGET = HuaGoScan2
                        }
                    }
                }
            }
        }
    }
}

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    if (contains(DEFINES, USE_SCRIPT)) {
        RC_FILE += ../../../app/scanner2/resourceTmp.rc
    } else {
        RC_FILE += ../../../app/scanner2/resource.rc
    }
    DEFINES += LIBMOSQUITTO_STATIC
    MY_OS = windows

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(release, debug|release) {
        QMAKE_LFLAGS_RELEASE += /MAP
        QMAKE_CFLAGS_RELEASE += /Zi
        QMAKE_LFLAGS_RELEASE += /debug /opt:ref
    }

    INCLUDEPATH += $$PWD/../../../third_party/libmosquitto/$${MY_OS}/include
    LIBS += $$PWD/../../../third_party/libmosquitto/$${MY_OS}/lib/$${MY_ARCH}/mosquitto_static.lib
    LIBS += $$PWD/../../../third_party/openssl/$${MY_OS}/lib/$${MY_ARCH}/libcrypto.lib
    LIBS += $$PWD/../../../third_party/openssl/$${MY_OS}/lib/$${MY_ARCH}/libssl.lib

    LIBS += -lgdi32 -lgdiplus -ldbghelp -luser32 -ladvapi32 -lcrypt32 -lws2_32
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base -l$${OEM_PREFIX}ImgFmt -l$${OEM_PREFIX}ImgProc\
         -l$${OEM_PREFIX}TwainUser
    LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -lyuyanbao

    # sane.dll
    LIBS += -L$$PWD/../../../../release/win/$${MY_ARCH}/OEM/$${OEM_NAME}
}

unix {

    DEFINES += _GLIBCXX_USE_CXX11_ABI=0
    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }

    contains(QT_ARCH, x86_64) {
        DEFINES += x86_64
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        DEFINES += aarch64
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        DEFINES += mips64
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        DEFINES += loongarch64
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }
    contains(QT_ARCH, sw_64) {
		DEFINES += sw_64
        MY_ARCH = sw_64
        MY_ARCH2 = sw_64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base -l$${OEM_PREFIX2}ImgFmt -l$${OEM_PREFIX2}ImgProc\
            -l$${OEM_PREFIX2}TwainUI -l$${OEM_PREFIX2}SaneUser

    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -lyuyanbao
}

INCLUDEPATH += $$PWD/../../../app/scanner2
INCLUDEPATH += $$PWD/../../../modules
INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

win32 {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $${PWD}/../../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTEXE_PATH = $$replace(DESTEXE_PATH, /, \\)
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}.exe
        SRCEXE_FILE = $$replace(SRCEXE_FILE, /, \\)
        message(SRCEXE_FILE: $$SRCEXE_FILE)
        SRCPDB_FILE = $${DESTDIR}/$${TARGET}.pdb
        SRCPDB_FILE = $$replace(SRCPDB_FILE, /, \\)
        message(SRCPDB_FILE: $$SRCPDB_FILE)

        QMAKE_POST_LINK += xcopy /y \"$$SRCEXE_FILE\" $$DESTEXE_PATH && xcopy /y \"$$SRCPDB_FILE\" $$DESTEXE_PATH
    }
}

unix {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2}/
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}
        message(SRCEXE_FILE: $$SRCEXE_FILE)

        QMAKE_POST_LINK += cp \"$$SRCEXE_FILE\" $$DESTEXE_PATH
    }
}

SOURCES +=   \
    ../../../app/scanner2/HGImgThumb.cpp \
    ../../../app/scanner2/HGImgView.cpp \
    ../../../app/scanner2/HGUIGlobal.cpp \
    ../../../app/scanner2/VersionDll.cpp \
    ../../../app/scanner2/app_cfg.cpp \
    ../../../app/scanner2/dialog_admin.cpp \
    ../../../app/scanner2/dialog_aquireinto.cpp \
    ../../../app/scanner2/dialog_clrcache.cpp \
    ../../../app/scanner2/dialog_export.cpp \
    ../../../app/scanner2/dialog_exportimagefile.cpp \
    ../../../app/scanner2/dialog_feedback.cpp \
    ../../../app/scanner2/dialog_fullscreen.cpp \
    ../../../app/scanner2/dialog_imageeditor.cpp \
    ../../../app/scanner2/dialog_imageinfo.cpp \
    ../../../app/scanner2/dialog_imgproc_adjust.cpp \
    ../../../app/scanner2/dialog_imgproc_autocrop.cpp \
    ../../../app/scanner2/dialog_input.cpp \
    ../../../app/scanner2/dialog_insertindex.cpp \
    ../../../app/scanner2/dialog_logmanager.cpp \
    ../../../app/scanner2/dialog_moveto.cpp \
    ../../../app/scanner2/dialog_multirotate.cpp \
    ../../../app/scanner2/dialog_multirotateimagefile.cpp \
    ../../../app/scanner2/dialog_openimageindex.cpp \
    ../../../app/scanner2/dialog_passwordchange.cpp \
    ../../../app/scanner2/dialog_saveas.cpp \
    ../../../app/scanner2/dialog_savemessagebox.cpp \
    ../../../app/scanner2/dialog_updateprogress.cpp \
    ../../../app/scanner2/dialog_upgrade.cpp \
    ../../../app/scanner2/dialog_writesettings.cpp \
    ../../../app/scanner2/dialog_waitingocr.cpp \
    ../../../app/scanner2/dialog_abnormalimage.cpp \
    ../../../app/scanner2/device_user.cpp \
    ../../../app/scanner2/graphicsscene.cpp \
    ../../../app/scanner2/main.cpp \
    ../../../app/scanner2/mainwindow.cpp \
    ../../../app/scanner2/mqtt.cpp \
    ../../../app/scanner2/widget_imgproc_base.cpp \
    ../../../app/scanner2/widget_statusbar.cpp \
    ../../../app/scanner2/widget_imgproc_sidebar.cpp \
    ../../../utility/HGString.cpp

HEADERS +=   \
    ../../../app/scanner2/custom_file_dialog.h\
    ../../../app/scanner2/HGImgThumb.h \
    ../../../app/scanner2/HGImgView.h \
    ../../../app/scanner2/HGUIGlobal.h \
    ../../../app/scanner2/VersionDll.h \
    ../../../app/scanner2/app_cfg.h \
    ../../../app/scanner2/dialog_admin.h \
    ../../../app/scanner2/dialog_aquireinto.h \
    ../../../app/scanner2/dialog_clrcache.h \
    ../../../app/scanner2/dialog_export.h \
    ../../../app/scanner2/dialog_exportimagefile.h \
    ../../../app/scanner2/dialog_feedback.h \
    ../../../app/scanner2/dialog_fullscreen.h \
    ../../../app/scanner2/dialog_imageeditor.h \
    ../../../app/scanner2/dialog_imageinfo.h \
    ../../../app/scanner2/dialog_imgproc_adjust.h \
    ../../../app/scanner2/dialog_imgproc_autocrop.h \
    ../../../app/scanner2/dialog_input.h \
    ../../../app/scanner2/dialog_insertindex.h \
    ../../../app/scanner2/dialog_logmanager.h \
    ../../../app/scanner2/dialog_moveto.h \
    ../../../app/scanner2/dialog_multirotate.h \
    ../../../app/scanner2/dialog_multirotateimagefile.h \
    ../../../app/scanner2/dialog_openimageindex.h \
    ../../../app/scanner2/dialog_passwordchange.h \
    ../../../app/scanner2/dialog_saveas.h \
    ../../../app/scanner2/dialog_savemessagebox.h \
    ../../../app/scanner2/dialog_updateprogress.h \
    ../../../app/scanner2/dialog_upgrade.h \
    ../../../app/scanner2/dialog_writesettings.h \
    ../../../app/scanner2/dialog_waitingocr.h \
    ../../../app/scanner2/dialog_abnormalimage.h \
    ../../../app/scanner2/device_user.h \
    ../../../app/scanner2/graphicsscene.h \
    ../../../app/scanner2/mainwindow.h \
    ../../../app/scanner2/mqtt.h \
    ../../../app/scanner2/widget_imgproc_base.h \
    ../../../app/scanner2/widget_statusbar.h \
    ../../../app/scanner2/widget_imgproc_sidebar.h \
    ../../../utility/HGString.h

FORMS +=   \
    ../../../app/scanner2/dialog_admin.ui \
    ../../../app/scanner2/dialog_aquireinto.ui \
    ../../../app/scanner2/dialog_clrcache.ui \
    ../../../app/scanner2/dialog_export.ui \
    ../../../app/scanner2/dialog_exportimagefile.ui \
    ../../../app/scanner2/dialog_feedback.ui \
    ../../../app/scanner2/dialog_fullscreen.ui \
    ../../../app/scanner2/dialog_imageeditor.ui \
    ../../../app/scanner2/dialog_imageinfo.ui \
    ../../../app/scanner2/dialog_imgproc_adjust.ui \
    ../../../app/scanner2/dialog_imgproc_autocrop.ui \
    ../../../app/scanner2/dialog_input.ui \
    ../../../app/scanner2/dialog_insertindex.ui \
    ../../../app/scanner2/dialog_logmanager.ui \
    ../../../app/scanner2/dialog_moveto.ui \
    ../../../app/scanner2/dialog_multirotate.ui \
    ../../../app/scanner2/dialog_multirotateimagefile.ui \
    ../../../app/scanner2/dialog_openimageindex.ui \
    ../../../app/scanner2/dialog_passwordchange.ui \
    ../../../app/scanner2/dialog_saveas.ui \
    ../../../app/scanner2/dialog_savemessagebox.ui \
    ../../../app/scanner2/dialog_updateprogress.ui \
    ../../../app/scanner2/dialog_upgrade.ui \
    ../../../app/scanner2/dialog_writesettings.ui \
    ../../../app/scanner2/dialog_waitingocr.ui \
    ../../../app/scanner2/dialog_abnormalimage.ui \
    ../../../app/scanner2/mainwindow.ui \
    ../../../app/scanner2/widget_imgproc_base.ui \
    ../../../app/scanner2/widget_statusbar.ui \
    ../../../app/scanner2/widget_imgproc_sidebar.ui

RESOURCES +=  \
    ../../../app/scanner2/Scanner_resource.qrc

TRANSLATIONS +=  \
    ../../../app/scanner2/Scanner_zh_CN.ts \
    ../../../app/scanner2/Scanner_zh_TW.ts \
    ../../../app/scanner2/Scanner_zh_EN.ts \
    ../../../app/scanner2/qt_zh_CN.ts