CONFIG -= qt

TEMPLATE = app
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

include($$PWD/../HGOEM.pri)

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    if (contains(DEFINES, USE_SCRIPT)) {
        RC_FILE += ../../../sdk/webservice/resourceTmp.rc
    } else {
        RC_FILE += ../../../sdk/webservice/resource.rc
    }
    DEFINES += CURL_STATICLIB
    DEFINES += ZIP_STATIC
    MY_OS = windows
    TARGET = $${OEM_PREFIX}WebService

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(debug, debug|release) {
        QMAKE_CFLAGS_DEBUG += -MTd
        QMAKE_CXXFLAGS_DEBUG += -MTd
        LIBS += $$PWD/../../../third_party/libcurl/$${MY_OS}/lib/$${MY_ARCH}/libcurld.lib
    }
    CONFIG(release, debug|release) {
        QMAKE_CFLAGS_RELEASE += -MT
        QMAKE_CXXFLAGS_RELEASE += -MT
        QMAKE_LFLAGS_RELEASE += /MAP
        QMAKE_CFLAGS_RELEASE += /Zi
        QMAKE_LFLAGS_RELEASE += /debug /opt:ref
        LIBS += $$PWD/../../../third_party/libcurl/$${MY_OS}/lib/$${MY_ARCH}/libcurl.lib
    }

    LIBS += -lgdi32 -lgdiplus -ldbghelp -lws2_32 -lShell32 -lUser32 -lwldap32 -lAdvapi32
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base -l$${OEM_PREFIX}ImgFmt -l$${OEM_PREFIX}ImgProc
    LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -lsanexy
    INCLUDEPATH += $$PWD/../../../third_party/libzip/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/libcurl/$${MY_OS}/include
    LIBS += $$PWD/../../../third_party/zlib/$${MY_OS}/lib/$${MY_ARCH}/zlib.lib
    LIBS += $$PWD/../../../third_party/libzip/$${MY_OS}/lib/$${MY_ARCH}/zip.lib

    # sane.dll
    LIBS += -L$$PWD/../../../../release/win/$${MY_ARCH}/OEM/$${OEM_NAME}
}

unix {

    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }
    TARGET = $${OEM_PREFIX2}WebService

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }
    contains(QT_ARCH, sw_64) {
        MY_ARCH = sw_64
        MY_ARCH2 = sw_64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base -l$${OEM_PREFIX2}ImgFmt -l$${OEM_PREFIX2}ImgProc
    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -lsane-$${OEM_PREFIX3}sane
    INCLUDEPATH += $$PWD/../../../third_party/libzip/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/libcurl/$${MY_OS}/$${MY_ARCH}/include
    LIBS += $$PWD/../../../third_party/libzip/$${MY_OS}/$${MY_ARCH}/lib/libzip.a
    LIBS += $$PWD/../../../third_party/zlib/$${MY_OS}/$${MY_ARCH}/lib/libz.a
    LIBS += $$PWD/../../../third_party/libcurl/$${MY_OS}/$${MY_ARCH}/lib/libcurl.a
    contains(QT_ARCH, sw_64) {
        LIBS += $$PWD/../../../third_party/openssl/$${MY_OS}/$${MY_ARCH}/lib/libcrypto.a
        LIBS += $$PWD/../../../third_party/openssl/$${MY_OS}/$${MY_ARCH}/lib/libssl.a
    }
}

INCLUDEPATH += $$PWD/../../../modules
INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../third_party/sqlite
INCLUDEPATH += $$PWD/../../../third_party/json
INCLUDEPATH += $$PWD/../../../third_party/sha1
INCLUDEPATH += $$PWD/../../../third_party/base64
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_PREFIX3: $$OEM_PREFIX3)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

win32 {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $${PWD}/../../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTEXE_PATH = $$replace(DESTEXE_PATH, /, \\)
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}.exe
        SRCEXE_FILE = $$replace(SRCEXE_FILE, /, \\)
        message(SRCEXE_FILE: $$SRCEXE_FILE)
        SRCPDB_FILE = $${DESTDIR}/$${TARGET}.pdb
        SRCPDB_FILE = $$replace(SRCPDB_FILE, /, \\)
        message(SRCPDB_FILE: $$SRCPDB_FILE)

        QMAKE_POST_LINK += xcopy /y $$SRCEXE_FILE $$DESTEXE_PATH && xcopy /y $$SRCPDB_FILE $$DESTEXE_PATH
    }
}

unix {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2}/
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}
        message(SRCEXE_FILE: $$SRCEXE_FILE)

        QMAKE_POST_LINK += cp $$SRCEXE_FILE $$DESTEXE_PATH
    }
}

SOURCES +=   \
    ../../../sdk/webservice/HttpHead.cpp \
    ../../../sdk/webservice/HttpServer.cpp \
    ../../../sdk/webservice/HttpUser.cpp \
    ../../../sdk/webservice/Manager.cpp \
    ../../../sdk/webservice/ManagerV1.cpp \
    ../../../sdk/webservice/ManagerV2.cpp \
    ../../../sdk/webservice/MsgPumpCallback.cpp \
    ../../../sdk/webservice/SockIoServer.cpp \
    ../../../sdk/webservice/SockIoUser.cpp \
    ../../../sdk/webservice/WSServer.cpp \
    ../../../sdk/webservice/WSUser.cpp \
    ../../../sdk/webservice/WebServer.cpp \
    ../../../sdk/webservice/WebUser.cpp \
    ../../../sdk/webservice/main.cpp \
    ../../../third_party/base64/base64.cpp \
    ../../../third_party/json/cJSON.c \
    ../../../third_party/sha1/sha1.cpp \
    ../../../third_party/sqlite/sqlite3.c \
    ../../../utility/HGString.cpp

HEADERS +=   \
    ../../../sdk/webservice/HttpHead.h \
    ../../../sdk/webservice/HttpServer.h \
    ../../../sdk/webservice/HttpUser.h \
    ../../../sdk/webservice/Manager.h \
    ../../../sdk/webservice/ManagerV1.h \
    ../../../sdk/webservice/ManagerV2.h \
    ../../../sdk/webservice/Msg.h \
    ../../../sdk/webservice/MsgPumpCallback.h \
    ../../../sdk/webservice/SockIoServer.h \
    ../../../sdk/webservice/SockIoUser.h \
    ../../../sdk/webservice/WSServer.h \
    ../../../sdk/webservice/WSUser.h \
    ../../../sdk/webservice/WebServer.h \
    ../../../sdk/webservice/WebUser.h \
    ../../../sdk/webservice/resource.h \
    ../../../third_party/base64/base64.h \
    ../../../third_party/json/cJSON.h \
    ../../../third_party/sha1/sha1.h \
    ../../../third_party/sqlite/sqlite3.h \
    ../../../third_party/sqlite/sqlite3ext.h \
    ../../../utility/HGString.h