QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++11
QMAKE_CXXFLAGS += -std=c++0x
# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += QT_NO_VERSION_TAGGING

# OEM definition
DEFINES += OEM_HUAGAO

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

if (contains(DEFINES, OEM_HANWANG) || contains(DEFINES, OEM_LISICHENG) || contains(DEFINES, OEM_CANGTIAN) || contains(DEFINES, OEM_ZHONGJING)) {
    contains(DEFINES, OEM_HANWANG) {
        RC_ICONS = ../../../app/scanner/image_rsc/logo/Hanvon_logo1.ico
        TARGET = HanvonScan
    }
    contains(DEFINES, OEM_LISICHENG) {
        RC_ICONS = ../../../app/scanner/image_rsc/logo/Lanxum_logo.ico
        TARGET = LanxumScan
    }
    contains(DEFINES, OEM_CANGTIAN) {
        RC_ICONS = ../../../app/scanner/image_rsc/logo/Cumtenn_logo.ico
        TARGET = CumtennScan
    }
    contains(DEFINES, OEM_ZHONGJING) {
        RC_ICONS = ../../../app/scanner/image_rsc/logo/Microtek_logo.ico
        TARGET = MicrotekScan
    }
} else {
    RC_ICONS = ../../../app/scanner/image_rsc/logo/logo.ico
    TARGET = HuaGoScan
}

win32 {
        DEFINES += _CRT_SECURE_NO_WARNINGS
        QMAKE_LFLAGS += /MANIFESTUAC:"level='requireAdministrator' uiAccess='false'"

        if (contains(DEFINES, OEM_HANWANG) || contains(DEFINES, OEM_LISICHENG) || contains(DEFINES, OEM_CANGTIAN) || contains(DEFINES, OEM_ZHONGJING)) {
            contains(DEFINES, OEM_HANWANG) {
                LIBS += -lHWBase -lHWImgFmt -lHWImgProc
                contains(QT_ARCH, i386) {
                        LIBS += -L../../../../sdk/lib/win/x86/OEM/hanvon -lsane
                }
                contains(QT_ARCH, x86_64){
                        LIBS += -L../../../../sdk/lib/win/x64/OEM/hanvon -lsane
                }
            }
            contains(DEFINES, OEM_LISICHENG) {
                LIBS += -lLSCBase -lLSCImgFmt -lLSCImgProc
                contains(QT_ARCH, i386) {
                        LIBS += -L../../../../sdk/lib/win/x86/OEM/lanxum -lsane
                }
                contains(QT_ARCH, x86_64){
                        LIBS += -L../../../../sdk/lib/win/x64/OEM/lanxum -lsane
                }
            }
            contains(DEFINES, OEM_CANGTIAN) {
                LIBS += -lCTSBase -lCTSImgFmt -lCTSImgProc
                contains(QT_ARCH, i386) {
                        LIBS += -L../../../../sdk/lib/win/x86/OEM/cumtenn -lsane
                }
                contains(QT_ARCH, x86_64){
                        LIBS += -L../../../../sdk/lib/win/x64/OEM/cumtenn -lsane
                }
            }
            contains(DEFINES, OEM_ZHONGJING) {
                LIBS += -lZJBase -lZJImgFmt -lZJImgProc
                contains(QT_ARCH, i386) {
                        LIBS += -L../../../../sdk/lib/win/x86/OEM/microtek -lsane
                }
                contains(QT_ARCH, x86_64){
                        LIBS += -L../../../../sdk/lib/win/x64/OEM/microtek -lsane
                }
            }
        } else {
            LIBS += -lHGBase -lHGImgFmt -lHGImgProc
            contains(QT_ARCH, i386) {
                    LIBS += -L../../../../sdk/lib/win/x86/OEM/huagao -lsane
            }
            contains(QT_ARCH, x86_64){
                    LIBS += -L../../../../sdk/lib/win/x64/OEM/huagao -lsane
            }
        }

        contains(QT_ARCH, i386) {
                LIBS += -L../../../../sdk/lib/win/x86/Release
                CONFIG(release, debug|release) {
                        DESTDIR = ../../../../release/win/x86/Release/
                }
                CONFIG(debug, debug|release) {

                }
        }
        contains(QT_ARCH, x86_64){
                LIBS += -L../../../../sdk/lib/win/x64/Release
                CONFIG(release, debug|release) {
                        DESTDIR = ../../../../release/win/x64/Release/
                }
                CONFIG(debug, debug|release) {

                }
        }
}

unix {
        LIBS += -llang
        QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
        DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
        message($$DISTRIBUTION)
        ARCH = $$system(arch)
        message($$ARCH)
        QMAKE_LFLAGS += -Wl,-rpath=.

        if (contains(DEFINES, OEM_HANWANG) || contains(DEFINES, OEM_LISICHENG) || contains(DEFINES, OEM_CANGTIAN) || contains(DEFINES, OEM_ZHONGJING)) {
            contains(DEFINES, OEM_HANWANG){
                LIBS += -lHwBase -lHwImgFmt -lHwImgProc -lsane-hwsane -lhwdriver
            }
            contains(DEFINES, OEM_LISICHENG){
                LIBS += -lLscBase -lLscImgFmt -lLscImgProc -lsane-lscsane -llscdriver
            }
            contains(DEFINES, OEM_CANGTIAN){
                LIBS += -lCtsBase -lCtsImgFmt -lCtsImgProc -lsane-ctssane -lctsdriver
            }
            contains(DEFINES, OEM_ZHONGJING){
                LIBS += -lZjBase -lZjImgFmt -lZjImgProc -lsane-zjsane -lzjdriver
            }
        } else {
            LIBS += -lHGBase -lHGImgFmt -lHGImgProc -lsane-hgsane -lhgdriver
        }

        contains(DISTRIBUTION, UnionTech){
                message('UOS')
                DEFINES += UOS

                contains(ARCH, x86_64){
                        DEFINES += x86_64
                        LIBS += -L../../../../release/uos/x86_64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/uos/x86_64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
                contains(ARCH, aarch64){
                        DEFINES += aarch64
                        LIBS += -L../../../../release/uos/aarch64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/uos/aarch64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
                contains(ARCH, mips64){
                        DEFINES += mips64
                        LIBS += -L../../../../release/uos/mips64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/uos/mips64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
                contains(ARCH, loongarch64){
                        DEFINES += loongarch64
                        LIBS += -L../../../../release/uos/loongarch64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/uos/loongarch64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
        } else {
                message('KYLIN')
                DEFINES += KYLIN

                contains(ARCH, x86_64){
                        DEFINES += x86_64
                        LIBS += -L../../../../release/kylin/x86_64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/kylin/x86_64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
                contains(ARCH, aarch64){
                        DEFINES += aarch64
                        LIBS += -L../../../../release/kylin/aarch64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/kylin/aarch64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
                contains(ARCH, mips64){
                        DEFINES += mips64
                        LIBS += -L../../../../release/kylin/mips64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/kylin/mips64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
                contains(ARCH, loongarch64){
                        DEFINES += loongarch64
                        LIBS += -L../../../../release/kylin/loongarch64
                        CONFIG(release, debug|release) {
                                DESTDIR = ../../../../release/kylin/loongarch64/
                        }
                        CONFIG(debug, debug|release) {

                        }
                }
        }
}

INCLUDEPATH += $$PWD/../../../app/scanner/
INCLUDEPATH += $$PWD/../../../utility/
INCLUDEPATH += $$PWD/../../../modules/
INCLUDEPATH += $$PWD/../../../../sdk/include/

SOURCES += \
    ../../../app/scanner/VersionDll.cpp \
    ../../../app/scanner/app_cfg.cpp \
    ../../../app/scanner/cutdialog.cpp \
    ../../../app/scanner/cutpapertool.cpp \
    ../../../app/scanner/device_menu.cpp \
    ../../../app/scanner/dialog_aquireinto.cpp \
    ../../../app/scanner/dialog_clrcache.cpp \
    ../../../app/scanner/dialog_export.cpp \
    ../../../app/scanner/dialog_exportimagefile.cpp \
    ../../../app/scanner/dialog_fullscreen.cpp \
    ../../../app/scanner/dialog_imageeditor.cpp \
    ../../../app/scanner/dialog_imageinfo.cpp \
    ../../../app/scanner/dialog_imgproc_adjust.cpp \
    ../../../app/scanner/dialog_imgproc_autocrop.cpp \
    ../../../app/scanner/dialog_insertindex.cpp \
    ../../../app/scanner/dialog_logmanager.cpp \
    ../../../app/scanner/dialog_moveto.cpp \
    ../../../app/scanner/dialog_multirotate.cpp \
    ../../../app/scanner/dialog_multirotateimagefile.cpp \
    ../../../app/scanner/dialog_openimageindex.cpp \
    ../../../app/scanner/dialog_passwordchange.cpp \
    ../../../app/scanner/dialog_saveas.cpp \
    ../../../app/scanner/dialog_writesettings.cpp \
    ../../../app/scanner/gaosixy.cpp \
    ../../../app/scanner/graphicsscene.cpp \
    ../../../app/scanner/hg_settingdialog.cpp \
    ../../../app/scanner/main.cpp \
    ../../../app/scanner/mainwindow.cpp \
    ../../../app/scanner/sane_device.cpp \
    ../../../app/scanner/setpicclrtool.cpp \
    ../../../app/scanner/widget.cpp \
    ../../../app/scanner/widget_imgproc_base.cpp \
    ../../../app/scanner/widget_statusbar.cpp \
    ../../../app/scanner/dialog_admin.cpp \
    ../../../app/scanner/dialog_log.cpp \
    ../../../app/scanner/cfg/gb_json.cpp \
    ../../../app/scanner/cfg/cJSON.c \
    ../../../app/scanner/HGImgThumb.cpp \
    ../../../app/scanner/HGImgView.cpp \
    ../../../app/scanner/HGUIGlobal.cpp \
    ../../../utility/HGString.cpp \
    ../../../app/scanner/dialog_input.cpp \
    ../../../app/scanner/dialog_updateprogress.cpp \
    ../../../app/scanner/dialog_upgrade.cpp \
    ../../../app/scanner/dialog_feedback.cpp \
    ../../../app/scanner/dialog_wrong_img.cpp \
    ../../../app/scanner/dialog_upgradefirmware.cpp \
    ../../../app/scanner/dialog_savemessagebox.cpp

HEADERS += \
    ../../../app/scanner/VersionDll.h \
    ../../../app/scanner/app_cfg.h \
    ../../../app/scanner/cutdialog.h \
    ../../../app/scanner/cutpapertool.h \
    ../../../app/scanner/device_menu.h \
    ../../../app/scanner/dialog_aquireinto.h \
    ../../../app/scanner/dialog_clrcache.h \
    ../../../app/scanner/dialog_export.h \
    ../../../app/scanner/dialog_exportimagefile.h \
    ../../../app/scanner/dialog_fullscreen.h \
    ../../../app/scanner/dialog_imageeditor.h \
    ../../../app/scanner/dialog_imageinfo.h \
    ../../../app/scanner/dialog_imgproc_adjust.h \
    ../../../app/scanner/dialog_imgproc_autocrop.h \
    ../../../app/scanner/dialog_insertindex.h \
    ../../../app/scanner/dialog_logmanager.h \
    ../../../app/scanner/dialog_moveto.h \
    ../../../app/scanner/dialog_multirotate.h \
    ../../../app/scanner/dialog_multirotateimagefile.h \
    ../../../app/scanner/dialog_openimageindex.h \
    ../../../app/scanner/dialog_passwordchange.h \
    ../../../app/scanner/dialog_saveas.h \
    ../../../app/scanner/dialog_writesettings.h \
    ../../../app/scanner/gaosixy.h \
    ../../../app/scanner/graphicsscene.h \
    ../../../app/scanner/hg_settingdialog.h \
    ../../../app/scanner/mainwindow.h \
    ../../../app/scanner/sane_device.h \
    ../../../app/scanner/setpicclrtool.h \
    ../../../app/scanner/widget.h \
    ../../../app/scanner/widget_imgproc_base.h \
    ../../../app/scanner/widget_statusbar.h \
    ../../../app/scanner/dialog_admin.h \
    ../../../app/scanner/dialog_log.h \
    ../../../app/scanner/cfg/gb_json.h \
    ../../../app/scanner/cfg/cJSON.h \
    ../../../app/scanner/HGImgThumb.h \
    ../../../app/scanner/HGImgView.h \
    ../../../app/scanner/HGUIGlobal.h \
    ../../../utility/HGString.h \
    ../../../app/scanner/dialog_input.h \
    ../../../app/scanner/custom_file_dialog.h \
    ../../../app/scanner/dialog_updateprogress.h \
    ../../../app/scanner/dialog_upgrade.h \
    ../../../app/scanner/dialog_feedback.h \
    ../../../app/scanner/dialog_wrong_img.h \
    ../../../app/scanner/dialog_upgradefirmware.h \
    ../../../app/scanner/dialog_savemessagebox.h

FORMS += \
    ../../../app/scanner/cutdialog.ui \
    ../../../app/scanner/cutpapertool.ui \
    ../../../app/scanner/dialog_admin.ui \
    ../../../app/scanner/dialog_aquireinto.ui \
    ../../../app/scanner/dialog_clrcache.ui \
    ../../../app/scanner/dialog_export.ui \
    ../../../app/scanner/dialog_exportimagefile.ui \
    ../../../app/scanner/dialog_fullscreen.ui \
    ../../../app/scanner/dialog_imageeditor.ui \
    ../../../app/scanner/dialog_imageinfo.ui \
    ../../../app/scanner/dialog_imgproc_adjust.ui \
    ../../../app/scanner/dialog_imgproc_autocrop.ui \
    ../../../app/scanner/dialog_insertindex.ui \
    ../../../app/scanner/dialog_logmanager.ui \
    ../../../app/scanner/dialog_moveto.ui \
    ../../../app/scanner/dialog_multirotate.ui \
    ../../../app/scanner/dialog_multirotateimagefile.ui \
    ../../../app/scanner/dialog_openimageindex.ui \
    ../../../app/scanner/dialog_passwordchange.ui \
    ../../../app/scanner/dialog_saveas.ui \
    ../../../app/scanner/dialog_writesettings.ui \
    ../../../app/scanner/mainwindow.ui \
    ../../../app/scanner/setpicclrtool.ui \
    ../../../app/scanner/widget.ui \
    ../../../app/scanner/widget_imgproc_base.ui \
    ../../../app/scanner/widget_statusbar.ui \
    ../../../app/scanner/dialog_log.ui \
    ../../../app/scanner/dialog_input.ui \
    ../../../app/scanner/dialog_updateprogress.ui \
    ../../../app/scanner/dialog_upgrade.ui \
    ../../../app/scanner/dialog_feedback.ui \
    ../../../app/scanner/dialog_wrong_img.ui \
    ../../../app/scanner/dialog_upgradefirmware.ui \
    ../../../app/scanner/dialog_savemessagebox.ui

TRANSLATIONS += \
    ../../../app/scanner/Scanner_zh_CN.ts \
    ../../../app/scanner/Scanner_zh_EN.ts \
    ../../../app/scanner/qt_zh_CN.ts

RESOURCES += \
    ../../../app/scanner/Scanner_resource.qrc

DISTFILES += \
    ../../../app/scanner/Scanner_zh_CN.qm \
    ../../../app/scanner/Scanner_zh_EN.qm \
    ../../../app/scanner/qt_zh_CN.qm