QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += QT_NO_VERSION_TAGGING

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

include($$PWD/../HGOEM.pri)

if (contains(DEFINES, OEM_HANWANG)) {
    RC_ICONS = ../../../app/scanner/image_rsc/logo/Hanvon_logo1.ico
    TARGET = HanvonScan
} else {
    if (contains(DEFINES, OEM_LISICHENG)) {
        RC_ICONS = ../../../app/scanner/image_rsc/logo/Lanxum_logo.ico
        TARGET = LanxumScan
    } else {
        if (contains(DEFINES, OEM_CANGTIAN)) {
            RC_ICONS = ../../../app/scanner/image_rsc/logo/Cumtenn_logo.ico
            TARGET = CumtennScan
        } else {
            if (contains(DEFINES, OEM_ZHONGJING)) {
                RC_ICONS = ../../../app/scanner/image_rsc/logo/Microtek_logo.ico
                TARGET = MicrotekScan
            } else {
                if (contains(DEFINES, OEM_ZIGUANG)) {
                    RC_ICONS = ../../../app/scanner/image_rsc/logo/uniscan.ico
                    TARGET = UniScan
                } else {
                    if (contains(DEFINES, OEM_NEUTRAL)) {
                        RC_ICONS = ../../../app/scanner/image_rsc/logo/NoBrand_logo.ico
                        TARGET = NeuScan
                    } else {
                        if (contains(DEFINES, OEM_DELI)) {
                            RC_ICONS = ../../../app/scanner/image_rsc/logo/deli.ico
                            TARGET = "DELI SCAN"
                        } else {
                            RC_ICONS = ../../../app/scanner/image_rsc/logo/logo.ico
                            TARGET = HuaGoScan
                        }
                    }
                }
            }
        }
    }
}

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    MY_OS = windows

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(release, debug|release) {
        QMAKE_LFLAGS_RELEASE += /MAP
        QMAKE_CFLAGS_RELEASE += /Zi
        QMAKE_LFLAGS_RELEASE += /debug /opt:ref
    }

    LIBS += -lgdi32 -lgdiplus -ldbghelp -luser32 -ladvapi32
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base -l$${OEM_PREFIX}ImgFmt \
        -l$${OEM_PREFIX}ImgProc
    LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -lsane -llang

    # sane.dll
    LIBS += -L$$PWD/../../../../release/win/$${MY_ARCH}/OEM/$${OEM_NAME}
}

unix {

    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }
    contains(QT_ARCH, sw_64) {
        MY_ARCH = sw_64
        MY_ARCH2 = sw_64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
 #   QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base -l$${OEM_PREFIX2}ImgFmt \
        -l$${OEM_PREFIX2}ImgProc
    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -lsane-$${OEM_PREFIX3}sane -llang
}

INCLUDEPATH += $$PWD/../../../app/scanner
INCLUDEPATH += $$PWD/../../../modules
INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

win32 {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $${PWD}/../../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTEXE_PATH = $$replace(DESTEXE_PATH, /, \\)
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}.exe
        SRCEXE_FILE = $$replace(SRCEXE_FILE, /, \\)
        message(SRCEXE_FILE: $$SRCEXE_FILE)
        SRCPDB_FILE = $${DESTDIR}/$${TARGET}.pdb
        SRCPDB_FILE = $$replace(SRCPDB_FILE, /, \\)
        message(SRCPDB_FILE: $$SRCPDB_FILE)

        QMAKE_POST_LINK += xcopy /y \"$$SRCEXE_FILE\" $$DESTEXE_PATH && xcopy /y \"$$SRCPDB_FILE\" $$DESTEXE_PATH
    }
}

unix {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2}/
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}
        message(SRCEXE_FILE: $$SRCEXE_FILE)

        QMAKE_POST_LINK += cp $$SRCEXE_FILE $$DESTEXE_PATH
    }
}

SOURCES +=   \
    ../../../app/scanner/HGImgThumb.cpp \
    ../../../app/scanner/HGImgView.cpp \
    ../../../app/scanner/HGUIGlobal.cpp \
    ../../../app/scanner/VersionDll.cpp \
    ../../../app/scanner/app_cfg.cpp \
    ../../../app/scanner/cfg/cJSON.c \
    ../../../app/scanner/cfg/gb_json.cpp \
    ../../../app/scanner/cutdialog.cpp \
    ../../../app/scanner/cutpapertool.cpp \
    ../../../app/scanner/device_menu.cpp \
    ../../../app/scanner/dialog_admin.cpp \
    ../../../app/scanner/dialog_aquireinto.cpp \
    ../../../app/scanner/dialog_clrcache.cpp \
    ../../../app/scanner/dialog_export.cpp \
    ../../../app/scanner/dialog_exportimagefile.cpp \
    ../../../app/scanner/dialog_feedback.cpp \
    ../../../app/scanner/dialog_fullscreen.cpp \
    ../../../app/scanner/dialog_imageeditor.cpp \
    ../../../app/scanner/dialog_imageinfo.cpp \
    ../../../app/scanner/dialog_imgproc_adjust.cpp \
    ../../../app/scanner/dialog_imgproc_autocrop.cpp \
    ../../../app/scanner/dialog_input.cpp \
    ../../../app/scanner/dialog_insertindex.cpp \
    ../../../app/scanner/dialog_log.cpp \
    ../../../app/scanner/dialog_logmanager.cpp \
    ../../../app/scanner/dialog_moveto.cpp \
    ../../../app/scanner/dialog_multirotate.cpp \
    ../../../app/scanner/dialog_multirotateimagefile.cpp \
    ../../../app/scanner/dialog_openimageindex.cpp \
    ../../../app/scanner/dialog_passwordchange.cpp \
    ../../../app/scanner/dialog_saveas.cpp \
    ../../../app/scanner/dialog_savemessagebox.cpp \
    ../../../app/scanner/dialog_updateprogress.cpp \
    ../../../app/scanner/dialog_upgrade.cpp \
    ../../../app/scanner/dialog_upgradefirmware.cpp \
    ../../../app/scanner/dialog_writesettings.cpp \
    ../../../app/scanner/dialog_wrong_img.cpp \
    ../../../app/scanner/gaosixy.cpp \
    ../../../app/scanner/graphicsscene.cpp \
    ../../../app/scanner/hg_settingdialog.cpp \
    ../../../app/scanner/main.cpp \
    ../../../app/scanner/mainwindow.cpp \
    ../../../app/scanner/ocrPdf.cpp \
    ../../../app/scanner/sane_device.cpp \
    ../../../app/scanner/setpicclrtool.cpp \
    ../../../app/scanner/widget.cpp \
    ../../../app/scanner/widget_imgproc_base.cpp \
    ../../../app/scanner/widget_statusbar.cpp \
    ../../../app/scanner/widget_imgproc_sidebar.cpp \
    ../../../utility/HGString.cpp

HEADERS +=   \
    ../../../app/scanner/HGImgThumb.h \
    ../../../app/scanner/HGImgView.h \
    ../../../app/scanner/HGUIGlobal.h \
    ../../../app/scanner/VersionDll.h \
    ../../../app/scanner/app_cfg.h \
    ../../../app/scanner/cfg/cJSON.h \
    ../../../app/scanner/cfg/gb_json.h \
    ../../../app/scanner/custom_file_dialog.h \
    ../../../app/scanner/cutdialog.h \
    ../../../app/scanner/cutpapertool.h \
    ../../../app/scanner/device_menu.h \
    ../../../app/scanner/dialog_admin.h \
    ../../../app/scanner/dialog_aquireinto.h \
    ../../../app/scanner/dialog_clrcache.h \
    ../../../app/scanner/dialog_export.h \
    ../../../app/scanner/dialog_exportimagefile.h \
    ../../../app/scanner/dialog_feedback.h \
    ../../../app/scanner/dialog_fullscreen.h \
    ../../../app/scanner/dialog_imageeditor.h \
    ../../../app/scanner/dialog_imageinfo.h \
    ../../../app/scanner/dialog_imgproc_adjust.h \
    ../../../app/scanner/dialog_imgproc_autocrop.h \
    ../../../app/scanner/dialog_input.h \
    ../../../app/scanner/dialog_insertindex.h \
    ../../../app/scanner/dialog_log.h \
    ../../../app/scanner/dialog_logmanager.h \
    ../../../app/scanner/dialog_moveto.h \
    ../../../app/scanner/dialog_multirotate.h \
    ../../../app/scanner/dialog_multirotateimagefile.h \
    ../../../app/scanner/dialog_openimageindex.h \
    ../../../app/scanner/dialog_passwordchange.h \
    ../../../app/scanner/dialog_saveas.h \
    ../../../app/scanner/dialog_savemessagebox.h \
    ../../../app/scanner/dialog_updateprogress.h \
    ../../../app/scanner/dialog_upgrade.h \
    ../../../app/scanner/dialog_upgradefirmware.h \
    ../../../app/scanner/dialog_writesettings.h \
    ../../../app/scanner/dialog_wrong_img.h \
    ../../../app/scanner/gaosixy.h \
    ../../../app/scanner/graphicsscene.h \
    ../../../app/scanner/hg_settingdialog.h \
    ../../../app/scanner/mainwindow.h \
    ../../../app/scanner/ocrPdf.h \
    ../../../app/scanner/sane_device.h \
    ../../../app/scanner/setpicclrtool.h \
    ../../../app/scanner/widget.h \
    ../../../app/scanner/widget_imgproc_base.h \
    ../../../app/scanner/widget_statusbar.h \
    ../../../app/scanner/widget_imgproc_sidebar.h \
    ../../../utility/HGString.h

FORMS +=   \
    ../../../app/scanner/cutdialog.ui \
    ../../../app/scanner/cutpapertool.ui \
    ../../../app/scanner/dialog_admin.ui \
    ../../../app/scanner/dialog_aquireinto.ui \
    ../../../app/scanner/dialog_clrcache.ui \
    ../../../app/scanner/dialog_export.ui \
    ../../../app/scanner/dialog_exportimagefile.ui \
    ../../../app/scanner/dialog_feedback.ui \
    ../../../app/scanner/dialog_fullscreen.ui \
    ../../../app/scanner/dialog_imageeditor.ui \
    ../../../app/scanner/dialog_imageinfo.ui \
    ../../../app/scanner/dialog_imgproc_adjust.ui \
    ../../../app/scanner/dialog_imgproc_autocrop.ui \
    ../../../app/scanner/dialog_input.ui \
    ../../../app/scanner/dialog_insertindex.ui \
    ../../../app/scanner/dialog_log.ui \
    ../../../app/scanner/dialog_logmanager.ui \
    ../../../app/scanner/dialog_moveto.ui \
    ../../../app/scanner/dialog_multirotate.ui \
    ../../../app/scanner/dialog_multirotateimagefile.ui \
    ../../../app/scanner/dialog_openimageindex.ui \
    ../../../app/scanner/dialog_passwordchange.ui \
    ../../../app/scanner/dialog_saveas.ui \
    ../../../app/scanner/dialog_savemessagebox.ui \
    ../../../app/scanner/dialog_updateprogress.ui \
    ../../../app/scanner/dialog_upgrade.ui \
    ../../../app/scanner/dialog_upgradefirmware.ui \
    ../../../app/scanner/dialog_writesettings.ui \
    ../../../app/scanner/dialog_wrong_img.ui \
    ../../../app/scanner/mainwindow.ui \
    ../../../app/scanner/setpicclrtool.ui \
    ../../../app/scanner/widget.ui \
    ../../../app/scanner/widget_imgproc_base.ui \
    ../../../app/scanner/widget_statusbar.ui \
    ../../../app/scanner/widget_imgproc_sidebar.ui

RESOURCES +=  \
    ../../../app/scanner/Scanner_resource.qrc

TRANSLATIONS +=  \
    ../../../app/scanner/Scanner_zh_CN.ts \
    ../../../app/scanner/Scanner_zh_EN.ts \
    ../../../app/scanner/qt_zh_CN.ts