CONFIG -= qt

TEMPLATE = lib
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11
CONFIG += dll

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

DEFINES += OEM_HUAGAO

if (contains(DEFINES, OEM_HANWANG) || contains(DEFINES, OEM_LISICHENG) || contains(DEFINES, OEM_CANGTIAN) || contains(DEFINES, OEM_ZHONGJING) || contains(DEFINES, OEM_ZIGUANG)) {
    contains(DEFINES, OEM_HANWANG) {
        OEM_PREFIX = HW
        OEM_PREFIX2 = Hw
        OEM_PREFIX3 = hw
        OEM_NAME = hanvon
    }
    contains(DEFINES, OEM_LISICHENG) {
        OEM_PREFIX = LSC
        OEM_PREFIX2 = Lsc
        OEM_PREFIX3 = lsc
        OEM_NAME = lanxum
    }
    contains(DEFINES, OEM_CANGTIAN) {
        OEM_PREFIX = CTS
        OEM_PREFIX2 = Cts
        OEM_PREFIX3 = cts
        OEM_NAME = cumtenn
    }
    contains(DEFINES, OEM_ZHONGJING) {
        OEM_PREFIX = ZJ
        OEM_PREFIX2 = Zj
        OEM_PREFIX3 = zj
        OEM_NAME = microtek
    }
    contains(DEFINES, OEM_ZIGUANG) {
        OEM_PREFIX = ZG
        OEM_PREFIX2 = Zg
        OEM_PREFIX3 = zg
        OEM_NAME = unis
    }
} else {
    OEM_PREFIX = HG
    OEM_PREFIX2 = HG
    OEM_PREFIX3 = hg
    OEM_NAME = huagao
}

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    MY_OS = windows
    TARGET = $${OEM_PREFIX}ScannerLib

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(debug, debug|release) {
        QMAKE_CFLAGS_DEBUG += -MTd
        QMAKE_CXXFLAGS_DEBUG += -MTd
    }
    CONFIG(release, debug|release) {
        QMAKE_CFLAGS_RELEASE += -MT
        QMAKE_CXXFLAGS_RELEASE += -MT
    }

    DEF_FILE = HGScannerLib.def
    LIBS += -lgdi32 -lgdiplus -ldbghelp
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base -l$${OEM_PREFIX}ImgFmt -l$${OEM_PREFIX}ImgProc
    LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -lsane
}

unix {

    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }
    TARGET = $${OEM_PREFIX2}ScannerLib

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base -l$${OEM_PREFIX2}ImgFmt -l$${OEM_PREFIX2}ImgProc
    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -lsane-$${OEM_PREFIX3}sane
}

INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../modules/base
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_PREFIX3: $$OEM_PREFIX3)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

SOURCES +=   \
    ../../../sdk/scannerlib/HGLibDeviceImpl.cpp \
    ../../../sdk/scannerlib/HGScannerLib.cpp \
    ../../../utility/HGString.cpp

HEADERS +=   \
    ../../../sdk/scannerlib/HGLibDeviceImpl.hpp \
    ../../../sdk/scannerlib/HGScannerLib.h \
    ../../../utility/HGString.h