QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets gui-private

TEMPLATE = lib
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11
CONFIG += dll

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += QT_NO_VERSION_TAGGING

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

include($$PWD/../HGOEM.pri)

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    MY_OS = windows
    TARGET = $${OEM_PREFIX}SaneUI

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(debug, debug|release) {
        QMAKE_LFLAGS_DEBUG += /NOENTRY
    }
    CONFIG(release, debug|release) {
        QMAKE_LFLAGS_RELEASE += /MAP
        QMAKE_CFLAGS_RELEASE += /Zi
        QMAKE_LFLAGS_RELEASE += /debug /opt:ref
        QMAKE_LFLAGS_RELEASE += /NOENTRY
    }

    #DEF_FILE = HGSaneUI.def
    #LIBS += -lgdi32 -lgdiplus -ldbghelp -luser32
    #LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base
    #LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -llang
}

unix {

    SOURCES +=  \
        ../../../modules/saneui/HGSaneUI.cpp \
        ../../../modules/saneui/cfg/cJSON.c \
        ../../../modules/saneui/cfg/gb_json.cpp \
        ../../../modules/saneui/cutdialog.cpp \
        ../../../modules/saneui/cutpapertool.cpp \
        ../../../modules/saneui/device_menu.cpp \
        ../../../modules/saneui/dialog_device_scan.cpp \
        ../../../modules/saneui/dialog_device_select.cpp \
        ../../../modules/saneui/dialog_input.cpp \
        ../../../modules/saneui/dllmain.cpp \
        ../../../modules/saneui/gaosixy.cpp \
        ../../../modules/saneui/hg_settingdialog.cpp \
        ../../../modules/saneui/setpicclrtool.cpp \
        ../../../modules/saneui/widget.cpp \
        ../../../utility/HGString.cpp \
        ../../../modules/saneui/dialog_source_select.cpp

    HEADERS +=  \
        ../../../modules/saneui/HGSaneUI.h \
        ../../../modules/saneui/cfg/cJSON.h \
        ../../../modules/saneui/cfg/gb_json.h \
        ../../../modules/saneui/cutdialog.h \
        ../../../modules/saneui/cutpapertool.h \
        ../../../modules/saneui/device_menu.h \
        ../../../modules/saneui/dialog_device_scan.h \
        ../../../modules/saneui/dialog_device_select.h \
        ../../../modules/saneui/dialog_input.h \
        ../../../modules/saneui/gaosixy.h \
        ../../../modules/saneui/hg_settingdialog.h \
        ../../../modules/saneui/setpicclrtool.h \
        ../../../modules/saneui/widget.h \
        ../../../utility/HGString.h \
        ../../../modules/saneui/dialog_source_select.h

    FORMS += \
        ../../../modules/saneui/cutdialog.ui \
        ../../../modules/saneui/cutpapertool.ui \
        ../../../modules/saneui/dialog_device_scan.ui \
        ../../../modules/saneui/dialog_device_select.ui \
        ../../../modules/saneui/dialog_input.ui \
        ../../../modules/saneui/setpicclrtool.ui \
        ../../../modules/saneui/widget.ui \
        ../../../modules/saneui/dialog_source_select.ui

    RESOURCES += \
        ../../../modules/saneui/SaneUI_resource.qrc

    TRANSLATIONS +=  \
        ../../../modules/saneui/SaneUI_zh_CN.ts \
        ../../../modules/saneui/SaneUI_zh_EN.ts \
        ../../../modules/saneui/qt_zh_CN.ts

    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }
    TARGET = $${OEM_PREFIX2}SaneUI

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base
    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -llang
}

INCLUDEPATH += $$PWD/../../../modules
INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../modules/saneui
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

unix {

    CONFIG(release, debug|release) {
        DESTDLL_PATH = $$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2}/
        message(DESTDLL_PATH: $$DESTDLL_PATH)
        DESTHEADER_PATH = $${PWD}/../../../../sdk/include/saneui/
        message(DESTHEADER_PATH: $$DESTHEADER_PATH)

        SRCDLL_FILE = $${DESTDIR}/lib$${TARGET}.so
        message(SRCDLL_FILE: $$SRCDLL_FILE)
        SRCHEADER_FILE = $${PWD}/../../../modules/saneui/*.h
        message(SRCHEADER_FILE: $$SRCHEADER_FILE)

        QMAKE_POST_LINK += cp $$SRCDLL_FILE $$DESTDLL_PATH && cp $$SRCHEADER_FILE $$DESTHEADER_PATH
    }
}