QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += QT_NO_VERSION_TAGGING

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

include($$PWD/../HGOEM.pri)

if (contains(DEFINES, OEM_HANWANG)) {
    RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/Hanvon_logo1.ico
} else {
    if (contains(DEFINES, OEM_LISICHENG)) {
        RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/Lanxum_logo.ico
    } else {
        if (contains(DEFINES, OEM_CANGTIAN)) {
            RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/Cumtenn_logo.ico
        } else {
            if (contains(DEFINES, OEM_ZHONGJING)) {
                RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/Microtek_logo.ico
            } else {
                if (contains(DEFINES, OEM_ZIGUANG)) {
                    RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/uniscan.ico
                } else {
                    if (contains(DEFINES, OEM_NEUTRAL)) {
                        RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/NoBrand_logo.ico
                    } else {
                        if (contains(DEFINES, OEM_DELI)) {
                            RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/deli.ico
                        } else {
                            RC_ICONS = ../../../app/fwupgrade/image_rsc/logo/logo.ico
                        }
                    }
                }
            }
        }
    }
}

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    MY_OS = windows
    TARGET = $${OEM_PREFIX}FWUpgradeApp

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(release, debug|release) {
        QMAKE_LFLAGS_RELEASE += /MAP
        QMAKE_CFLAGS_RELEASE += /Zi
        QMAKE_LFLAGS_RELEASE += /debug /opt:ref
    }

    LIBS += -lgdi32 -lgdiplus -ldbghelp -luser32 -ladvapi32
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base -l$${OEM_PREFIX}ImgFmt \
        -l$${OEM_PREFIX}ImgProc -l$${OEM_PREFIX}Version
    LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -lsane

    # sane.dll
    LIBS += -L$$PWD/../../../../release/win/$${MY_ARCH}/OEM/$${OEM_NAME}
}

unix {

    DEFINES += _GLIBCXX_USE_CXX11_ABI=0
    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }
    TARGET = $${OEM_PREFIX2}FWUpgradeApp

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base -l$${OEM_PREFIX2}ImgFmt \
        -l$${OEM_PREFIX2}ImgProc -l$${OEM_PREFIX2}Version
    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -lsane-$${OEM_PREFIX3}sane
}

INCLUDEPATH += $$PWD/../../../modules
INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

win32 {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $${PWD}/../../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTEXE_PATH = $$replace(DESTEXE_PATH, /, \\)
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}.exe
        SRCEXE_FILE = $$replace(SRCEXE_FILE, /, \\)
        message(SRCEXE_FILE: $$SRCEXE_FILE)
        SRCPDB_FILE = $${DESTDIR}/$${TARGET}.pdb
        SRCPDB_FILE = $$replace(SRCPDB_FILE, /, \\)
        message(SRCPDB_FILE: $$SRCPDB_FILE)

        QMAKE_POST_LINK += xcopy /y $$SRCEXE_FILE $$DESTEXE_PATH && xcopy /y $$SRCPDB_FILE $$DESTEXE_PATH
    }
}

unix {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2}/
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}
        message(SRCEXE_FILE: $$SRCEXE_FILE)

        QMAKE_POST_LINK += cp $$SRCEXE_FILE $$DESTEXE_PATH
    }
}

SOURCES +=   \
    ../../../app/fwupgrade/dialog_updateprogress.cpp \
    ../../../app/fwupgrade/dialog_upgradefirmware.cpp \
    ../../../app/fwupgrade/logindialog.cpp \
    ../../../app/fwupgrade/main.cpp \
    ../../../app/fwupgrade/mainwindow.cpp \
    ../../../utility/HGString.cpp

HEADERS +=   \
    ../../../app/fwupgrade/dialog_updateprogress.h \
    ../../../app/fwupgrade/dialog_upgradefirmware.h \
    ../../../app/fwupgrade/logindialog.h \
    ../../../app/fwupgrade/mainwindow.h \
    ../../../utility/HGString.h

FORMS +=   \
    ../../../app/fwupgrade/dialog_updateprogress.ui \
    ../../../app/fwupgrade/dialog_upgradefirmware.ui \
    ../../../app/fwupgrade/logindialog.ui \
    ../../../app/fwupgrade/mainwindow.ui

RESOURCES +=  \
    ../../../app/fwupgrade/FWUpgrade_resource.qrc

TRANSLATIONS +=  \
    ../../../app/fwupgrade/FWUpgrade_zh_CN.ts \
    ../../../app/fwupgrade/qt_zh_CN.ts