QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets gui-private

TEMPLATE = lib
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11
CONFIG += dll

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += QT_NO_VERSION_TAGGING

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

include($$PWD/../HGOEM.pri)

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    SOURCES += ../../../modules/twainui/qmfcapp.cpp
    SOURCES += ../../../modules/twainui/qwinhost.cpp
    SOURCES += ../../../modules/twainui/qwinwidget.cpp
    HEADERS += ../../../modules/twainui/qmfcapp.hpp
    HEADERS += ../../../modules/twainui/qwinhost.hpp
    HEADERS += ../../../modules/twainui/qwinwidget.hpp
		
    MY_OS = windows
    TARGET = $${OEM_PREFIX}TwainUI

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(release, debug|release) {
        QMAKE_LFLAGS_RELEASE += /MAP
        QMAKE_CFLAGS_RELEASE += /Zi
        QMAKE_LFLAGS_RELEASE += /debug /opt:ref
    }

    DEF_FILE = HGTwainUI.def
    LIBS += -lgdi32 -lgdiplus -ldbghelp -luser32 -lShell32
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base
    LIBS += -L$$PWD/../../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -llang
}

unix {

    DEFINES += _GLIBCXX_USE_CXX11_ABI=0
    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }
    TARGET = $${OEM_PREFIX2}TwainUI

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
        MY_ARCH2 = x86_64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
        MY_ARCH2 = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
        MY_ARCH2 = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
        MY_ARCH2 = loongarch64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base
    LIBS += -L$$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2} -llang
}

INCLUDEPATH += $$PWD/../../../modules
INCLUDEPATH += $$PWD/../../../utility
INCLUDEPATH += $$PWD/../../../modules/twainui
INCLUDEPATH += $$PWD/../../../../sdk/include

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

win32 {

    CONFIG(release, debug|release) {
        DESTLIB_PATH = $${PWD}/../../../../sdk/lib/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTLIB_PATH = $$replace(DESTLIB_PATH, /, \\)
        message(DESTLIB_PATH: $$DESTLIB_PATH)
        DESTDLL_PATH = $${PWD}/../../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTDLL_PATH = $$replace(DESTDLL_PATH, /, \\)
        message(DESTDLL_PATH: $$DESTDLL_PATH)
        DESTHEADER_PATH = $${PWD}/../../../../sdk/include/twainui/
        DESTHEADER_PATH = $$replace(DESTHEADER_PATH, /, \\)
        message(DESTHEADER_PATH: $$DESTHEADER_PATH)

        SRCLIB_FILE = $${DESTDIR}/$${TARGET}.lib
        SRCLIB_FILE = $$replace(SRCLIB_FILE, /, \\)
        message(SRCLIB_FILE: $$SRCLIB_FILE)
        SRCDLL_FILE = $${DESTDIR}/$${TARGET}.dll
        SRCDLL_FILE = $$replace(SRCDLL_FILE, /, \\)
        message(SRCDLL_FILE: $$SRCDLL_FILE)
        SRCHEADER_FILE = $${PWD}/../../../modules/twainui/twainui.h
        SRCHEADER_FILE = $$replace(SRCHEADER_FILE, /, \\)
        message(SRCHEADER_FILE: $$SRCHEADER_FILE)
        SRCPDB_FILE = $${DESTDIR}/$${TARGET}.pdb
        SRCPDB_FILE = $$replace(SRCPDB_FILE, /, \\)
        message(SRCPDB_FILE: $$SRCPDB_FILE)

        QMAKE_POST_LINK += xcopy /y $$SRCLIB_FILE $$DESTLIB_PATH && xcopy /y $$SRCDLL_FILE $$DESTDLL_PATH \
            && xcopy /y $$SRCHEADER_FILE $$DESTHEADER_PATH && xcopy /y $$SRCPDB_FILE $$DESTDLL_PATH
    }
}

unix {

    CONFIG(release, debug|release) {
        DESTDLL_PATH = $$PWD/../../../../release/$${MY_OS}/$${MY_ARCH2}/
        message(DESTDLL_PATH: $$DESTDLL_PATH)
        DESTHEADER_PATH = $${PWD}/../../../../sdk/include/twainui/
        message(DESTHEADER_PATH: $$DESTHEADER_PATH)

        SRCDLL_FILE = $${DESTDIR}/lib$${TARGET}.so
        message(SRCDLL_FILE: $$SRCDLL_FILE)
        SRCHEADER_FILE = $${PWD}/../../../modules/twainui/twainui.h
        message(SRCHEADER_FILE: $$SRCHEADER_FILE)

        QMAKE_POST_LINK += cp $$SRCDLL_FILE $$DESTDLL_PATH && cp $$SRCHEADER_FILE $$DESTHEADER_PATH
    }
}

SOURCES += ../../../modules/twainui/twainui.cpp
HEADERS += ../../../modules/twainui/twainui.h
SOURCES += ../../../modules/twainui/hg_settingdialog.cpp
HEADERS += ../../../modules/twainui/hg_settingdialog.h

SOURCES +=  \
        ../../../modules/twainui/app_cfg.cpp \
        ../../../modules/twainui/HGUIGlobal.cpp \
        ../../../modules/twainui/Manager.cpp \
        ../../../modules/twainui/cfg/cJSON.c \
        ../../../modules/twainui/cfg/gb_json.cpp \
        ../../../modules/twainui/cutdialog.cpp \
        ../../../modules/twainui/cutpapertool.cpp \
        ../../../modules/twainui/device_menu.cpp \
        ../../../modules/twainui/dialog_input.cpp \
        ../../../modules/twainui/dllmain.cpp \
        ../../../modules/twainui/gaosixy.cpp \
        ../../../modules/twainui/setpicclrtool.cpp \
        ../../../utility/HGString.cpp \
        ../../../modules/twainui/widget.cpp \
        ../../../modules/twainui/dialog_progress_ui.cpp \
        ../../../modules/twainui/dialog_device_select.cpp \
        ../../../modules/twainui/dialog_twain_source_select.cpp \
        ../../../modules/twainui/dialog_source_select.cpp

HEADERS +=  \
        ../../../modules/twainui/app_cfg.h \
        ../../../modules/twainui/HGUIGlobal.h \
        ../../../modules/twainui/Manager.h \
        ../../../modules/twainui/cfg/cJSON.h \
        ../../../modules/twainui/cfg/gb_json.h \
        ../../../modules/twainui/cutdialog.h \
        ../../../modules/twainui/cutpapertool.h \
        ../../../modules/twainui/device_menu.h \
        ../../../modules/twainui/dialog_input.h \
        ../../../modules/twainui/gaosixy.h \
        ../../../modules/twainui/setpicclrtool.h \
        ../../../utility/HGString.h \
        ../../../modules/twainui/widget.h \
        ../../../modules/twainui/dialog_progress_ui.h \
        ../../../modules/twainui/dialog_device_select.h \
        ../../../modules/twainui/dialog_twain_source_select.h \
        ../../../modules/twainui/dialog_source_select.h

FORMS += \
        ../../../modules/twainui/cutdialog.ui \
        ../../../modules/twainui/cutpapertool.ui \
        ../../../modules/twainui/dialog_input.ui \
        ../../../modules/twainui/setpicclrtool.ui \
        ../../../modules/twainui/widget.ui \
        ../../../modules/twainui/dialog_progress_ui.ui \
        ../../../modules/twainui/dialog_device_select.ui \
        ../../../modules/twainui/dialog_twain_source_select.ui \
        ../../../modules/twainui/dialog_source_select.ui

RESOURCES += \
        ../../../modules/twainui/TwainUI_resource.qrc

TRANSLATIONS +=  \
        ../../../modules/twainui/TwainUI_zh_CN.ts \
        ../../../modules/twainui/TwainUI_zh_EN.ts \
        ../../../modules/twainui/qt_zh_CN.ts