CONFIG -= qt

TEMPLATE = lib
DEFINES += UNTITLED_LIBRARY

CONFIG += c++11
CONFIG += dll

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

DEFINES += OEM_HUAGAO

if (contains(DEFINES, OEM_HANWANG) || contains(DEFINES, OEM_LISICHENG) || contains(DEFINES, OEM_CANGTIAN) || contains(DEFINES, OEM_ZHONGJING) || contains(DEFINES, OEM_ZIGUANG)) {
    contains(DEFINES, OEM_HANWANG) {
        OEM_PREFIX = HW
        OEM_PREFIX2 = Hw
        OEM_NAME = hanvon
    }
    contains(DEFINES, OEM_LISICHENG) {
        OEM_PREFIX = LSC
        OEM_PREFIX2 = Lsc
        OEM_NAME = lanxum
    }
    contains(DEFINES, OEM_CANGTIAN) {
        OEM_PREFIX = CTS
        OEM_PREFIX2 = Cts
        OEM_NAME = cumtenn
    }
    contains(DEFINES, OEM_ZHONGJING) {
        OEM_PREFIX = ZJ
        OEM_PREFIX2 = Zj
        OEM_NAME = microtek
    }
    contains(DEFINES, OEM_ZIGUANG) {
        OEM_PREFIX = ZG
        OEM_PREFIX2 = Zg
        OEM_NAME = unis
    }
} else {
    OEM_PREFIX = HG
    OEM_PREFIX2 = HG
    OEM_NAME = huagao
}

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

win32 {

    DEFINES += ZIP_STATIC
    MY_OS = windows
    TARGET = $${OEM_PREFIX}ImgFmt

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    CONFIG(debug, debug|release) {
        QMAKE_CFLAGS_DEBUG += -MTd
        QMAKE_CXXFLAGS_DEBUG += -MTd
        LIBS += $$PWD/../../../third_party/tinyxml2/$${MY_OS}/lib/$${MY_ARCH}/tinyxml2d.lib
    }
    CONFIG(release, debug|release) {
        QMAKE_CFLAGS_RELEASE += -MT
        QMAKE_CXXFLAGS_RELEASE += -MT
        LIBS += $$PWD/../../../third_party/tinyxml2/$${MY_OS}/lib/$${MY_ARCH}/tinyxml2.lib
    }

    DEF_FILE = HGImgFmt.def
    LIBS += -lgdi32 -lgdiplus -ldbghelp -lAdvapi32
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base
    INCLUDEPATH += $$PWD/../../../third_party/libjpeg/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/libnsbmp/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/libpng/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/zlib/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/libtiff/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/giflib/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/mupdf/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/pdflib/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/libzip/$${MY_OS}/include
    INCLUDEPATH += $$PWD/../../../third_party/tinyxml2/$${MY_OS}/include
    LIBS += $$PWD/../../../third_party/libjpeg/$${MY_OS}/lib/$${MY_ARCH}/jpeg.lib
    LIBS += $$PWD/../../../third_party/libnsbmp/$${MY_OS}/lib/$${MY_ARCH}/libnsbmp.lib
    LIBS += $$PWD/../../../third_party/libpng/$${MY_OS}/lib/$${MY_ARCH}/libpng16.lib
    LIBS += $$PWD/../../../third_party/zlib/$${MY_OS}/lib/$${MY_ARCH}/zlib.lib
    LIBS += $$PWD/../../../third_party/libtiff/$${MY_OS}/lib/$${MY_ARCH}/tiff.lib
    LIBS += $$PWD/../../../third_party/giflib/$${MY_OS}/lib/$${MY_ARCH}/giflib.lib
    LIBS += $$PWD/../../../third_party/libzip/$${MY_OS}/lib/$${MY_ARCH}/zip.lib
}

unix {

    DISTRIBUTION = $$system(cat /etc/issue | cut -d\' \' -f1)
    contains(DISTRIBUTION, UnionTech) {
        MY_OS = uos
    } else {
        MY_OS = kylin
    }
    TARGET = $${OEM_PREFIX2}ImgFmt

    contains(QT_ARCH, x86_64) {
        MY_ARCH = amd64
    }
    contains(QT_ARCH, arm64) {
        MY_ARCH = aarch64
    }
    contains(QT_ARCH, mips64) {
        MY_ARCH = mips64
    }
    contains(QT_ARCH, loongarch64) {
        MY_ARCH = loongarch64
    }

    CONFIG += unversioned_libname unversioned_soname
    QMAKE_CXXFLAGS += -fvisibility=hidden
    QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
    QMAKE_LFLAGS += -Wl,-rpath,\'\$\$ORIGIN\' -Wl,--exclude-libs,ALL
    QMAKE_LFLAGS += -z defs -B direct

    LIBS += -lpthread -ldl
    LIBS += -L$$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX2}Base
    INCLUDEPATH += $$PWD/../../../third_party/libjpeg/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/libnsbmp/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/zlib/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/libpng/$${MY_OS}/$${MY_ARCH}/include/libpng16
    INCLUDEPATH += $$PWD/../../../third_party/libtiff/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/giflib/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/libzip/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/tinyxml2/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/pdflib/$${MY_OS}/$${MY_ARCH}/include
    INCLUDEPATH += $$PWD/../../../third_party/mupdf/$${MY_OS}/$${MY_ARCH}/include
    LIBS += $$PWD/../../../third_party/libjpeg/$${MY_OS}/$${MY_ARCH}/lib/libjpeg.a
    LIBS += $$PWD/../../../third_party/libnsbmp/$${MY_OS}/$${MY_ARCH}/lib/libnsbmp.a
    LIBS += $$PWD/../../../third_party/libpng/$${MY_OS}/$${MY_ARCH}/lib/libpng16.a
    LIBS += $$PWD/../../../third_party/libtiff/$${MY_OS}/$${MY_ARCH}/lib/libtiff.a
    LIBS += $$PWD/../../../third_party/giflib/$${MY_OS}/$${MY_ARCH}/lib/libgiflib.a
    LIBS += $$PWD/../../../third_party/libzip/$${MY_OS}/$${MY_ARCH}/lib/libzip.a
    LIBS += $$PWD/../../../third_party/tinyxml2/$${MY_OS}/$${MY_ARCH}/lib/libtinyxml2.a
    LIBS += $$PWD/../../../third_party/zlib/$${MY_OS}/$${MY_ARCH}/lib/libz.a
}

INCLUDEPATH += $$PWD/../../../utility

DESTDIR = $$PWD/../../build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}
UI_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
MOC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
OBJECTS_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}
RCC_DIR = $$PWD/../../temp/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}/$${TARGET}

message(MY_OS: $$MY_OS)
message(MY_ARCH: $$MY_ARCH)
message(OEM_PREFIX: $$OEM_PREFIX)
message(OEM_PREFIX2: $$OEM_PREFIX2)
message(OEM_NAME: $$OEM_NAME)
message(MY_CONFIGURE: $$MY_CONFIGURE)
message(TARGET: $$TARGET)
message(DESTDIR: $$DESTDIR)
message(UI_DIR: $$UI_DIR)
message(MOC_DIR: $$MOC_DIR)
message(OBJECTS_DIR: $$OBJECTS_DIR)
message(RCC_DIR: $$RCC_DIR)

win32 {

    CONFIG(release, debug|release) {
        DESTLIB_PATH = $${PWD}/../../../../sdk/lib/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTLIB_PATH = $$replace(DESTLIB_PATH, /, \\)
        message(DESTLIB_PATH: $$DESTLIB_PATH)
        DESTDLL_PATH = $${PWD}/../../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTDLL_PATH = $$replace(DESTDLL_PATH, /, \\)
        message(DESTDLL_PATH: $$DESTDLL_PATH)
        DESTHEADER_PATH = $${PWD}/../../../../sdk/include/imgfmt/
        DESTHEADER_PATH = $$replace(DESTHEADER_PATH, /, \\)
        message(DESTHEADER_PATH: $$DESTHEADER_PATH)

        SRCLIB_FILE = $${DESTDIR}/$${TARGET}.lib
        SRCLIB_FILE = $$replace(SRCLIB_FILE, /, \\)
        message(SRCLIB_FILE: $$SRCLIB_FILE)
        SRCDLL_FILE = $${DESTDIR}/$${TARGET}.dll
        SRCDLL_FILE = $$replace(SRCDLL_FILE, /, \\)
        message(SRCDLL_FILE: $$SRCDLL_FILE)
        SRCHEADER_FILE = $${PWD}/../../../modules/imgfmt/*.h
        SRCHEADER_FILE = $$replace(SRCHEADER_FILE, /, \\)
        message(SRCHEADER_FILE: $$SRCHEADER_FILE)

        QMAKE_POST_LINK += xcopy /y $$SRCLIB_FILE $$DESTLIB_PATH && xcopy /y $$SRCDLL_FILE $$DESTDLL_PATH \
            && xcopy /y $$SRCHEADER_FILE $$DESTHEADER_PATH
    }
}

SOURCES += \
    ../../../modules/imgfmt/HGBmp.cpp \
    ../../../modules/imgfmt/HGGif.cpp \
    ../../../modules/imgfmt/HGImgFmt.cpp \
    ../../../modules/imgfmt/HGJpeg.cpp \
    ../../../modules/imgfmt/HGOfd.cpp \
    ../../../modules/imgfmt/HGOfdImpl.cpp \
    ../../../modules/imgfmt/HGPdf.cpp \
    ../../../modules/imgfmt/HGPdfImpl.cpp \
    ../../../modules/imgfmt/HGPng.cpp \
    ../../../modules/imgfmt/HGPnm.cpp \
    ../../../modules/imgfmt/HGTiff.cpp \
    ../../../utility/HGString.cpp

HEADERS += \
    ../../../modules/imgfmt/HGBmp.h \
    ../../../modules/imgfmt/HGGif.h \
    ../../../modules/imgfmt/HGImgFmt.h \
    ../../../modules/imgfmt/HGImgFmtErr.h \
    ../../../modules/imgfmt/HGJpeg.h \
    ../../../modules/imgfmt/HGOfd.h \
    ../../../modules/imgfmt/HGOfdImpl.hpp \
    ../../../modules/imgfmt/HGPdf.h \
    ../../../modules/imgfmt/HGPdfImpl.hpp \
    ../../../modules/imgfmt/HGPng.h \
    ../../../modules/imgfmt/HGPnm.h \
    ../../../modules/imgfmt/HGTiff.h \
    ../../../utility/HGString.h