QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++11

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

TARGET = ProductionTool

RC_ICONS = image_rsc/logo/logo.ico

CONFIG(debug, debug|release) {
    MY_CONFIGURE = Debug
}
CONFIG(release, debug|release) {
    MY_CONFIGURE = Release
}

MY_OS = windows
OEM_NAME = huagao
OEM_PREFIX = HG

win32 {

    contains(QT_ARCH, i386) {
        MY_ARCH = x86
    }
    contains(QT_ARCH, x86_64) {
        MY_ARCH = x64
    }

    LIBS += -L$$PWD/../../../code_app/build2/build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE} -l$${OEM_PREFIX}Base -l$${OEM_PREFIX}ImgFmt -l$${OEM_PREFIX}ImgProc
    LIBS += -L$$PWD/../../../sdk/lib/win/$${MY_ARCH}/OEM/$${OEM_NAME} -lsanexy

    # sane.dll
    LIBS += -L$$PWD/../../../release/win/$${MY_ARCH}/OEM/$${OEM_NAME}

#    LIBS += -L$$PWD/../../db/$${MY_CONFIGURE} -lHGPdtToolDb
    LIBS += -L$$PWD/../../code/base/$${MY_ARCH}/$${MY_CONFIGURE} -ltest
}

INCLUDEPATH += $$PWD/../../../sdk/include/
#INCLUDEPATH += $$PWD/../../db/HGPdtToolDb/
INCLUDEPATH += $$PWD/../../code/base/

DESTDIR = $$PWD/../../../code_app/build2/build/$${MY_OS}/$${OEM_NAME}/$${MY_ARCH}/$${MY_CONFIGURE}

win32 {

    CONFIG(release, debug|release) {
        DESTEXE_PATH = $${PWD}/../../../release/win/$${MY_ARCH}/$${MY_CONFIGURE}/
        DESTEXE_PATH = $$replace(DESTEXE_PATH, /, \\)
        message(DESTEXE_PATH: $$DESTEXE_PATH)

        SRCEXE_FILE = $${DESTDIR}/$${TARGET}.exe
        SRCEXE_FILE = $$replace(SRCEXE_FILE, /, \\)
        message(SRCEXE_FILE: $$SRCEXE_FILE)
        SRCPDB_FILE = $${DESTDIR}/$${TARGET}.pdb
        SRCPDB_FILE = $$replace(SRCPDB_FILE, /, \\)
        message(SRCPDB_FILE: $$SRCPDB_FILE)

        QMAKE_POST_LINK += xcopy /y $$SRCEXE_FILE $$DESTEXE_PATH && xcopy /y $$SRCPDB_FILE $$DESTEXE_PATH
    }
}

SOURCES += \
    ../../../code_app/utility/HGString.cpp \
    app_cfg.cpp \
    HGImgView.cpp \
    HGUIGlobal.cpp \
    analysisjson.cpp \
    dialog_accountmanage.cpp \
    dialog_changepwd.cpp \
    dialog_excepdesc.cpp \
    dialog_hgmessagebox.cpp \
    dialog_inputserialnum.cpp \
    dialog_login.cpp \
    dialog_rootfuntion.cpp \
    dialog_setburnsn.cpp \
    dialog_setlogpath.cpp \
    dialog_uploadcfgfile.cpp \
    dialog_userinput.cpp \
    dialog_registeraccount.cpp \
    form_burnmode.cpp \
    form_maininterface.cpp \
    form_texttips.cpp \
    hgscanner.cpp \
    main.cpp \
    mainwindow.cpp \
    ui_helper.cpp

HEADERS += \
    ../../../code_app/utility/HGString.h \
    app_cfg.h \
    HGImgView.h \
    HGUIGlobal.h \
    analysisjson.h \
    dialog_accountmanage.h \
    dialog_changepwd.h \
    dialog_excepdesc.h \
    dialog_hgmessagebox.h \
    dialog_inputserialnum.h \
    dialog_login.h \
    dialog_rootfuntion.h \
    dialog_setburnsn.h \
    dialog_setlogpath.h \
    dialog_uploadcfgfile.h \
    dialog_userinput.h \
    dialog_registeraccount.h \
    form_burnmode.h \
    form_maininterface.h \
    form_texttips.h \
    hgscanner.h \
    mainwindow.h \
    ui_helper.h

FORMS += \
    dialog_accountmanage.ui \
    dialog_changepwd.ui \
    dialog_excepdesc.ui \
    dialog_hgmessagebox.ui \
    dialog_inputserialnum.ui \
    dialog_login.ui \
    dialog_rootfuntion.ui \
    dialog_setburnsn.ui \
    dialog_setlogpath.ui \
    dialog_uploadcfgfile.ui \
    dialog_userinput.ui \
    dialog_registeraccount.ui \
    form_burnmode.ui \
    form_maininterface.ui \
    form_texttips.ui \
    mainwindow.ui

RESOURCES += \
    ProductionTool_resource.qrc

TRANSLATIONS += \
    ProductionTool_zh_CN.ts

DISTFILES += \
    ProductionTool_zh_CN.qm