code_twain/build_base.bat

@echo off
echo "Parameter 1:hg | lsc| hw | zj | cts | neu | dl"
echo "Parameter 2:x86 | x64 "

set OEM=%1
set CPU=%2
set OEM_DIR=""
set TMP_PATH=%~dp0..\tmp\%CPU%
set BIN_PATH=%~dp0..\release\win\%CPU%
set LIB_PATH=%~dp0..\sdk\lib\win\%CPU%
set COMMON_LIB_PATH=%LIB_PATH%\Release\

rem -----------------------------------------------------------------------------------------------------------------------------------

if "%OEM%" equ "hg" (
	set OEM_DIR=huagao
	set CL=/DOEM_HUAGAO /DBACKEND_NAME=hgsane
	goto oem
)
if "%OEM%" equ "hw" (
	set OEM_DIR=hanvon
	set CL=/DOEM_HANWANG /DBACKEND_NAME=hwsane
	goto oem
)
if "%OEM%" equ "lsc" (
	set OEM_DIR=lanxum
	set CL=/DOEM_LISICHENG /DBACKEND_NAME=lscsane
	goto oem
)
if "%OEM%" equ "zj" (
	set OEM_DIR=microtek
	set CL=/DOEM_ZHONGJING /DBACKEND_NAME=zjsane
	goto oem
)
if "%OEM%" equ "zg" (
	set OEM_DIR=unis
	set CL=/DOEM_ZIGUANG /DBACKEND_NAME=zgsane
	goto oem
)
if "%OEM%" equ "cts" (
	set OEM_DIR=cumtenn
	set CL=/DOEM_CANGTIAN /DBACKEND_NAME=ctssane
	goto oem
)
if "%OEM%" equ "neu" (
	set OEM_DIR=neutral
	set CL=/DOEM_NEUTRAL /DBACKEND_NAME=hgsane
	goto oem
)
if "%OEM%" equ "dl" (
	set OEM_DIR=deli
	set CL=/DOEM_DELI /DBACKEND_NAME=dlsane
	goto oem
)
echo "Parameter 1:oem is fail"
exit 1
:oem
echo %OEM%
rem -----------------------------------------------------------------------------------------------------------------------------------

if "%CPU%" equ "x64" 		 goto sys
if "%CPU%" equ "x86" 		 goto sys
echo "Parameter 2:sys is fail"
exit 1
:sys
echo %CPU%
rem -----------------------------------------------------------------------------------------------------------------------------------

set TMP_PATH=%TMP_PATH%\%OEM_DIR%\Release
set BIN_PATH=%BIN_PATH%\OEM\%OEM_DIR%
set LIB_PATH=%LIB_PATH%\OEM\%OEM_DIR%

rem -----------------------------------------------------------------------------------------------------------------------------------

echo oem=%OEM%
echo cpu=%CPU%
echo pe-path=%BIN_PATH%
echo lib-path=%LIB_PATH%
echo tmp-path=%TMP_PATH%

rem -----------------------------------------------------------------------------------------------------------------------------------

if "%VSCMD_VER%" neq "" goto compile
set dev=""
for /f "tokens=1,2,* " %%i in ('reg QUERY "HKEY_CLASSES_ROOT\CLSID\{2E1517DA-87BF-4443-984A-D2BF18F5A908}\LocalServer32" /ve') do set dev=%%k
echo dev=%dev%

if %dev% NEQ "" (
	call %dev%\..\..\..\vc\auxiliary\build\vcvars64.bat
)
:env

rem -----------------------------------------------------------------------------------------------------------------------------------

:compile

"%~dp0\sln\release\hgsetver.exe" "%~dp0\..\sdk\include\huagao\brand.h" -oem %OEM% -cpu %CPU% -nov

mkdir %LIB_PATH%
mkdir %COMMON_LIB_PATH%

MSBuild.exe "%~dp0\lang\lang.vcxproj" /p:Configuration=Release /p:Platform=%CPU% /p:IntDir=%TMP_PATH%\lang\ /p:OutDir=%BIN_PATH%\
if %ERRORLEVEL% neq 0 goto end
call :move_libs %BIN_PATH% lang %LIB_PATH%
copy /y %LIB_PATH%\lang.lib %COMMON_LIB_PATH%
MSBuild.exe "%~dp0\device\scanner.vcxproj" /p:Configuration=Release /p:Platform=%CPU% /p:IntDir=%TMP_PATH%\scanner\ /p:OutDir=%BIN_PATH%\
if %ERRORLEVEL% neq 0 goto end
call :move_libs %BIN_PATH% scanner %LIB_PATH%
copy /y %LIB_PATH%\scanner.lib %COMMON_LIB_PATH%
MSBuild.exe "%~dp0\sane\sane.vcxproj" /p:Configuration=Release /p:Platform=%CPU% /p:IntDir=%TMP_PATH%\sane\ /p:OutDir=%BIN_PATH%\
if %ERRORLEVEL% neq 0 goto end
call :move_libs %BIN_PATH% sane %LIB_PATH%
copy /y %LIB_PATH%\sane.lib %COMMON_LIB_PATH%
goto end

REM move_libs src_dir src_name dst_dir
 
:move_libs
move /Y "%1\%2.exp" "%3"
move /Y "%1\%2.lib" "%3"
move /Y "%1\%2.pdb" "%3"
EXIT /B 0

:end