; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
#define MyAppName "沧田扫描软件"
#define MyAppVersion GetFileVersion('..\..\x64\OEM\cumtenn\sanexy.dll')
#define MyAppSetupName "CumtennScan_App_Setup"
#define MyAppDefSetupDir "CumtennScan"
#define MyAppPublisher "浙江沧田智能信息科技有限公司"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{ADE66CB2-15FD-4BF8-BFA7-ED3E239C9ACE}
AppName={#MyAppName}
AppVerName={#MyAppName}
AppVersion={#MyAppVersion}
DefaultDirName={pf}\{#MyAppDefSetupDir}
DefaultGroupName={#MyAppName}
VersionInfoVersion={#MyAppVersion}
OutputDir=..\..\package
OutputBaseFilename={#MyAppSetupName}_{#MyAppVersion}
Compression=lzma
AppPublisher={#MyAppPublisher}
SolidCompression=no
UninstallIconFile=uninstall.ico
SetupIconFile=CumtennScan_App.ico
LicenseFile=CumtennScan_App_License.txt
AlwaysShowComponentsList=true
ArchitecturesInstallIn64BitMode=x64
;PrivilegesRequired=admin
DisableWelcomePage=no

[Languages]
Name: "zn"; MessagesFile: "compiler:Languages/ChineseSimp.isl" 

[Components]
;Name: "Upgrade"; Description: "在线升级功能" ; Types: Full
Name: "TwainG138"; Description: "CUMTENNSCAN G138 TWAIN" ; Types: Full
Name: "TwainG238"; Description: "CUMTENNSCAN G238 TWAIN" ; Types: Full
Name: "TwainG6005"; Description: "CUMTENNSCAN G6005 TWAIN" ; Types: Full
Name: "TwainG6006"; Description: "CUMTENNSCAN G6006 TWAIN" ; Types: Full                    

[Files]

; app
Source: ".\CumtennScan_App.ico"; DestDir: "{app}\"; Flags: ignoreversion
Source: "..\..\..\..\code_app\doc\scanner\CumtennScan_App_Help_manual.pdf"; DestDir: "{app}\"; Flags: ignoreversion
Source: "..\..\..\..\code_app\doc\scanner\CumtennScan_scanSettings_Help_manual.pdf"; DestDir: "{app}\"; Flags: ignoreversion

; app32
Source: "..\..\x86\Release\CTSTwainUI.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\CTSTwainUser.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\hwusbdev.key"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\tessdata\*"; DestDir: "{app}\tessdata\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\iconengines\*"; DestDir: "{app}\iconengines\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\imageformats\*"; DestDir: "{app}\imageformats\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\platforms\*"; DestDir: "{app}\platforms\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\styles\*"; DestDir: "{app}\styles\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\translations\*"; DestDir: "{app}\translations\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\*.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\CumtennScan2.exe"; DestDir: "{app}\"; DestName: "CumtennScan.exe"; Flags: ignoreversion; Check: not Is64BitInstallMode
;Source: "..\..\x86\Release\CTSUpgradeApp.exe"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\cnocr.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\doc_seg.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\ExportFile.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\FormEx.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\GetPdf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\GetRtf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\GetXls.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\hanwangOCRdetect.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\hasp_windows_113819.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\CTSBase.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\CTSImgFmt.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\CTSImgProc.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
;Source: "..\..\x86\Release\CTSVersion.dll"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\HwOcrSdk.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\libmupdf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\libzip.org.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\mp30.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\ofd.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\pdflib.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\PDFParse.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\tinyxml2.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\VC++\*.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\zlib.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\sanexy.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\scannerqd.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\yuyanbao.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\..\lang\*"; DestDir: "{app}\lang\"; Flags: ignoreversion; Check: not Is64BitInstallMode

; app64
Source: "..\..\x64\Release\CTSTwainUI.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\CTSTwainUser.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\hwusbdev.key"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\tessdata\*"; DestDir: "{app}\tessdata\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\iconengines\*"; DestDir: "{app}\iconengines\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\imageformats\*"; DestDir: "{app}\imageformats\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\platforms\*"; DestDir: "{app}\platforms\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\styles\*"; DestDir: "{app}\styles\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\translations\*"; DestDir: "{app}\translations\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\*.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\CumtennScan2.exe"; DestDir: "{app}\"; DestName: "CumtennScan.exe"; Flags: ignoreversion; Check: Is64BitInstallMode
;Source: "..\..\x64\Release\CTSUpgradeApp.exe"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: Is64BitInstallMode
Source: "..\..\x64\Release\cnocr.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\doc_seg.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\ExportFile.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\FormEx.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\GetPdf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\GetRtf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\GetXls.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\hanwangOCRdetect.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\hasp_windows_x64_113819.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\CTSBase.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\CTSImgFmt.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\CTSImgProc.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
;Source: "..\..\x64\Release\CTSVersion.dll"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: Is64BitInstallMode
Source: "..\..\x64\Release\HwOcrSdk.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\libmupdf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\libzip.org.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\mp30.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\ofd.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\pdflib.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\PDFParse.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\tinyxml2.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\VC++\*.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\zlib.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\OEM\cumtenn\sanexy.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\OEM\cumtenn\scannerqd.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\OEM\cumtenn\yuyanbao.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\..\lang\*"; DestDir: "{app}\lang\"; Flags: ignoreversion; Check: Is64BitInstallMode

;TWAINDSM
Source: "..\..\x86\Release\TWAINDSM.dll"; DestDir: "{sys}\"; Flags: ignoreversion onlyifdoesntexist; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\TWAINDSM.dll"; DestDir: "{syswow64}\"; Flags: ignoreversion onlyifdoesntexist; Check: Is64BitInstallMode
Source: "..\..\x64\Release\TWAINDSM.dll"; DestDir: "{sys}\"; Flags: ignoreversion onlyifdoesntexist; Check: Is64BitInstallMode

; twain32
Source: "..\..\x86\Release\CTSTwainUI.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\..\..\code_app\doc\scanner\CumtennScan_scanSettings_Help_manual.pdf"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\VC++\*.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\sanexy.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\scannerqd.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\yuyanbao.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\..\lang\*"; DestDir: "{win}\twain_32\CumtennTwain\lang\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\CTSBase.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\CTSImgFmt.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\CTSImgProc.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\CTSVersion.dll"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\tessdata\*"; DestDir: "{win}\twain_32\CumtennTwain\tessdata\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\cumtenn\cumtenntwain138.ds"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG138;
Source: "..\..\x86\OEM\cumtenn\cumtenntwain238.ds"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG238;
Source: "..\..\x86\OEM\cumtenn\cumtenntwain6005.ds"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG6005;
Source: "..\..\x86\OEM\cumtenn\cumtenntwain6006.ds"; DestDir: "{win}\twain_32\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG6006;

; twain64
Source: "..\..\x64\OEM\cumtenn\cumtenntwain138.ds"; DestDir: "{win}\twain_64\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG138;  Check: Is64BitInstallMode
Source: "..\..\x64\OEM\cumtenn\cumtenntwain238.ds"; DestDir: "{win}\twain_64\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG238;  Check: Is64BitInstallMode
Source: "..\..\x64\OEM\cumtenn\cumtenntwain6005.ds"; DestDir: "{win}\twain_64\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG6005;  Check: Is64BitInstallMode
Source: "..\..\x64\OEM\cumtenn\cumtenntwain6006.ds"; DestDir: "{win}\twain_64\CumtennTwain\"; Flags: ignoreversion;  Components: TwainG6006;  Check: Is64BitInstallMode

;拷贝驱动
Source: "..\..\usb\cumtenn\ctsusbscan.inf"; DestDir: "{app}\driver\";  Flags: ignoreversion recursesubdirs;
Source: "..\..\usb\cumtenn\ctsusbscan.cat"; DestDir: "{app}\driver\";  Flags: ignoreversion recursesubdirs;
Source: "..\..\x86\Release\DPInst32.exe"; DestDir: "{app}\";  Flags: ignoreversion recursesubdirs;  Check: not IsWin64
Source: "..\..\x64\Release\DPInst64.exe"; DestDir: "{app}\";  Flags: ignoreversion recursesubdirs;  Check: IsWin64

; 临时使用
Source: "..\..\x86\Release\RemoveOldApp.exe"; DestDir: "{tmp}\";  Flags: ignoreversion
Source: "..\..\x86\Release\CheckNewApp.exe"; DestDir: "{app}\";  Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x64\Release\CheckNewApp.exe"; DestDir: "{app}\";  Flags: ignoreversion; Check: Is64BitInstallMode

[INI]

[Icons]
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\CumtennScan.exe"
Name: "{group}\{#MyAppName}"; Filename: "{app}\CumtennScan.exe"
Name: "{group}\沧田扫描软件帮助文档"; Filename: "{app}\CumtennScan_App_Help_manual.pdf"
Name: "{group}\卸载"; Filename: "{uninstallexe}";

[Registry]
Root: HKLM; Subkey: "Software\CumtennScan"; ValueType: string; ValueName: "AppDirectory"; ValueData: "{app}"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\CumtennScan"; ValueType: string; ValueName: "Application"; ValueData: "{app}\CumtennScan.exe"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\CumtennScan"; ValueType: string; ValueName: "AppVersion"; ValueData: "{#MyAppVersion}"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\CumtennScan"; ValueType: string; ValueName: "DriverPath"; ValueData: "{app}"; Flags: uninsdeletekey;  Check: not Is64BitInstallMode
Root: HKLM; Subkey: "Software\CumtennScan"; ValueType: string; ValueName: "DriverPath"; ValueData: "{win}\twain_32\CumtennTwain"; Flags: uninsdeletekey;  Check: Is64BitInstallMode
Root: HKLM; Subkey: "Software\CumtennScan"; ValueType: string; ValueName: "DriverPath64"; ValueData: "{app}"; Flags: uninsdeletekey;  Check: Is64BitInstallMode
Root: HKLM; Subkey: "Software\WOW6432Node\CumtennScan"; ValueType: string; ValueName: "DriverPath"; ValueData: "{win}\twain_32\CumtennTwain"; Flags: uninsdeletekey;  Check: Is64BitInstallMode
Root: HKLM; Subkey: "Software\WOW6432Node\CumtennScan"; ValueType: string; ValueName: "DriverPath64"; ValueData: "{app}"; Flags: uninsdeletekey;  Check: Is64BitInstallMode

[Code]

var 
  globalInstallPath: String;
 
//初始化时把路径设置到编辑框
procedure InitializeWizard;
begin
  WizardForm.DirEdit.Text := globalInstallPath;
end;

function GetInstallString(): String;
var
  InstallPath: String;
begin
  InstallPath := ExpandConstant('{pf}\{#MyAppDefSetupDir}');
  if RegValueExists(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{ADE66CB2-15FD-4BF8-BFA7-ED3E239C9ACE}_is1', 'Inno Setup: App Path') then
    begin
      RegQueryStringValue(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{ADE66CB2-15FD-4BF8-BFA7-ED3E239C9ACE}_is1', 'Inno Setup: App Path', InstallPath)
    end
  result := InstallPath;
end;

function InitializeSetup(): boolean;
var
  ErrorCode: Integer;
  ResultCode: Integer;
  ResultStr: String;
  UninstallContinue: Boolean;
  CmdStr: String;
begin
  Result := false;
  globalInstallPath := GetInstallString();
  CmdStr := GetCmdTail();
  ExtractTemporaryFile('RemoveOldApp.exe');
  if Exec(ExpandConstant('{tmp}\RemoveOldApp.exe'), 'OEM_CANGTIAN', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode) then
  begin
    if 0 = ErrorCode then
    begin
      if RegQueryStringValue(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{ADE66CB2-15FD-4BF8-BFA7-ED3E239C9ACE}_is1', 'UninstallString', ResultStr) then
      begin
        UninstallContinue := true;
        if Pos('/verysilent', CmdStr) = 0 then
        begin
          if MsgBox('扫描软件已安装，是否卸载原版本？', mbConfirmation, MB_YESNO) <> IDYES then
          begin
            UninstallContinue := false;
          end
        end
        if UninstallContinue then
        begin
          ResultStr := RemoveQuotes(ResultStr);  
          if Exec(ResultStr, '/verysilent', '', SW_HIDE, ewWaitUntilTerminated, ResultCode) then
          begin
            if 0 = ResultCode then
            begin
              Sleep(1000)
              Result := true;
            end
          end
        end
      end
      else
      begin
        Result := true;
      end
    end
    else if 2 = ErrorCode then
    begin
      MsgBox('请先关闭旧版扫描软件！', mbInformation, MB_OK);
    end
    else
    begin
      MsgBox('卸载旧版扫描软件失败，停止安装！', mbInformation, MB_OK);
    end 
  end
end;

function SetUninstallIcon(iconPath:string): Boolean;
var
  InstalledVersion,SubKeyName: String;
begin
  SubKeyName :=  'Software\Microsoft\Windows\CurrentVersion\Uninstall\{ADE66CB2-15FD-4BF8-BFA7-ED3E239C9ACE}_is1';
  RegWriteStringValue(HKLM,SubKeyName,'DisplayIcon',iconPath);
end;

function InitializeUninstall(): Boolean;
var
  ErrorCode: Integer;
begin
  Result := false;
  if Exec(ExpandConstant('{app}\CheckNewApp.exe'), 'OEM_CANGTIAN', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode) then
  begin
    if 0 = ErrorCode then
    begin
      Result := true;
    end
    else
    begin
      MsgBox('请先关闭扫描软件！', mbInformation, MB_OK);
    end
  end
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpFinished then
  begin
    SetUninstallIcon(ExpandConstant('{app}\CumtennScan_App.ico'));
  end;
end;

procedure CurUninstallStepChanged(CurUninstallStep:TUninstallStep);
begin
  if CurUninstallStep = usDone then
  begin
    DelTree(ExpandConstant('{app}'), True, True, True);
    DelTree(ExpandConstant('{win}\twain_32\CumtennTwain'), True, True, True);
    DelTree(ExpandConstant('{win}\twain_64\CumtennTwain'), True, True, True);
  end;
 end;

[Run]
Filename: "{app}\DPInst32"; Parameters: "/path ""{app}\driver"" /sw /se /lm /f"; Check: not IsWin64
Filename: "{app}\DPInst64"; Parameters: "/path ""{app}\driver"" /sw /se /lm /f"; Check: IsWin64
;Filename: "{app}\CTSUpgradeApp.exe"; Parameters:"-type=postinstallinfo -appName=Scanner -oemName=Cumtenn -desc=install/upgrade";  Components: Upgrade
Filename: "{app}\CumtennScan.exe"; Description: "{cm:LaunchProgram, {#MyAppName}}"; Flags: postinstall nowait skipifsilent

[UninstallRun]
; 卸载驱动
;Filename: "{app}\DPInst32"; Parameters: "/u ""{app}\driver\cumtennusba3.inf"" /q /d"; Check: not IsWin64
;Filename: "{app}\DPInst64"; Parameters: "/u ""{app}\driver\cumtennusba3.inf"" /q /d"; Check: IsWin64
;Filename: "{app}\DPInst32"; Parameters: "/u ""{app}\driver\cumtennusba4.inf"" /q /d"; Check: not IsWin64
;Filename: "{app}\DPInst64"; Parameters: "/u ""{app}\driver\cumtennusba4.inf"" /q /d"; Check: IsWin64